COMMENT ⊗   VALID 00007 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	Editor Auxilliary routines }
C00031 00003	{ Externally defined routines from elsewhere: }
C00032 00004	(* aux routines: GetAChar, out1Line, clearLine, eUppercase, eEqStrng, eResLookup, eIdLookup *)
C00037 00005	(* aux routines: makeNVar, makeUVar, varLookup *)
C00042 00006	(* cursorStack routines: pushStmnt, pushNode *)
C00044 00007	(* bannerLine, borderLines, & adjustDisplay *)
C00048 ENDMK
C⊗;
{$NOMAIN	Editor Auxilliary routines }

(* definition of record types & global variables used by AL *)

const 

  maxLines = 28;
  maxPPLines = 12;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

type

(* random type declarations for OMSI/SAIL compatibility *)

 ascii = char;
 atext = text;
 byte = 0..255;	

(* Here are all the pointer-type definitions.  Since the various 	*)
(* records reference each other so much, we have to put them all here.	*)

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
identp = ↑ident;
tokenp = ↑token;
reswordp = ↑resword;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑message;
linerecp = ↑linerec;


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;
vector = record  refcnt: integer; val: array [1..3] of real end;
trans = record  refcnt: integer; val: array [1..3,1..4] of real end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;


(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    progtype:	    (pcode: statementp; errors: integer);
    blocktype,
    declaretype,
    endtype,
    coendtype:	    (bcode, bparent: statementp; blkid: identp;
			level, numvars: 0..255; variables: varidefp);
    coblocktype:    (threads: nodep; nthreads: integer; cblkid: identp);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: tokenp);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: identp);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    listnode:	(lval: nodep);
    clistnode:	(cval: integer; stmnt: statementp; clast: nodep);
    colistnode:	(prev: nodep; cstmnt: statementp);
    procdefnode:(ptype: datatypes; level: 0..255;
		    pname, paramlist: varidefp; body: statementp);
	end;



(* records for parser: ident, token, resword *)

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;


tokentypes = (reswdtype, identtype, constype, comnttype, delimtype, labeldeftype,
		macpartype);

constypes = svaltype..strngtype;

reswdtypes = (stmnttype, filtype, clsetype, decltype, optype, edittype);

filtypes = (abouttype,alongtype,attype,bytype,defertype,dotype,elsetype,
		errmodestype,fromtype,handtype,intype,nonrigidlytype,rigidlytype,
		sourcefiletype,steptype,thentype,totype,untltype,viatype,
		withtype,worldtype,zeroedtype,oftype,wheretype,nowaittype,
		ontype,offtype,ppsizetype,collecttype,alltype,lextype,
		notype,righttype,lefttype,uptype,downtype,motiontype);

clsetypes = (approachtype,arrivaltype,departuretype,departingtype,durationtype,
		errortype,forcetype,forceframetype,forcewristtype,gathertype,
		nildeproachtype,nullingtype,stiffnesstype,
		torquetype,velocitytype,wobbletype,
		cwtype,ccwtype,stopwaittimetype,angularvelocitytype,
		respecttype,elbowtype,shouldertype,fliptype,lineartype,
		jointspacetype,loadtype);

edittypes = (getcmd,savecmd,insertcmd,renamecmd,startcmd,gocmd,proceedcmd,
		stepcmd,sstepcmd,nstepcmd,gstepcmd,executecmd,setcmd,tracecmd,
		breakcmd,unbreakcmd,tbreakcmd,definecmd,markcmd,unmarkcmd,
		popcmd,atcmd,calibratecmd);

token = record
	  next: tokenp;
	  case ttype: tokentypes of
constype:   (cons: nodep);
comnttype:  (len: integer; str: strngp);
delimtype:  (ch: ascii);
reswdtype:  (case rtype: reswdtypes of
	stmnttype: (stmnt: stmntypes);
	filtype:   (filler: filtypes);
	clsetype:  (clause: clsetypes);
	decltype:  (decl: datatypes);
	optype:	   (op: exprtypes);
	edittype:  (ed: edittypes) );
identtype:  (id: identp);
labeldeftype: (lab: varidefp);
macpartype: (mpar: varidefp);
	end;


resword = record
	  next: reswordp;
	  length: integer;
	  name: strngp;
	  case rtype: reswdtypes of
	stmnttype:  (stmnt: stmntypes);
	filtype:    (filler: filtypes);
	clsetype:   (clause: clsetypes);
	decltype:   (decl: datatypes);
	optype:	    (op: exprtypes);
	edittype:  (ed: edittypes);
	  end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* definition of AL-ARM messages *)

msgtypes = (initarmscmd,calibcmd,killarmscmd,wherecmd,
	    abortcmd,stopcmd,movehdrcmd,movesegcmd,
	    centercmd,operatecmd,movedonecmd,signalcmd,
	    setccmd,forcesigcmd,forceoffcmd,biasoncmd,biasoffcmd,setstiffcmd,
	    zerowristcmd,wristcmd,gathercmd,getgathercmd,readadccmd,writedaccmd,
	    errorcmd,floatcmd,setloadcmd,
	    armmagiccmd,realcmd,vectorcmd,transcmd);

errortypes = (noerror,noarmsol,timerr,durerr,toolong,featna,
	      unkmess,srvdead,adcdead,nozind,exjtfc,paslim,nopower,badpot,devbusy,
	      baddev,timout,panicb,nocart,cbound,badparm);

message = record
	   cmd: msgtypes;
	   ok: boolean;
	   case integer of
	1:   (dev, bits, n: integer;
(*	     (dev, bits, n, evt: integer;	(* for arm code version *)
	      evt: eventp;
	      dur: real;
	      case integer of
		1: (v1,v2,v3: real);
		2: (sfac,wobble,pos: real);
		3: (val,angle,mag: real);
		4: (max,min: real);
		5: (error: errortypes));
	2:   (fv1,fv2,fv3,mv1,mv2,mv3: real);	(* may never use these... *)
	3:   (t: array [1..6] of real);
	  end;

interr = record
         case integer of
           0: (i: integer);
	   1: (err,foo: errortypes);
	 end;



(* print related records: *)

cursorp = record
	  cline,ind: integer;
	  case stmntp: boolean of
  true:    (st: statementp);
  false:   (nd: nodep);
	 end;

linerec = record
	next: linerecp;
	start,length: integer
       end;

listingarray = packed array [0..listinglength] of ascii;



(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
    lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii;
    lines: array [1..maxLines] of linerecp; (* what's on the screen + some *)
    ppLines: array [1..maxPPLines] of linerecp;	(* for page printer *)
    marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
    smartTerminal: boolean; (* true = insert/delete, false = redraw line *)
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
    nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;		(* set by GO *)
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines from elsewhere: }

	(* From ALLOC *)
function newVaridef: varidefp;					external;
function newStatement: statementp;				external;

	(* From DISP *)
procedure outLine(line,col,start,length: integer); 		external;
function getChar: ascii; 					external;

(* aux routines: GetAChar, out1Line, clearLine, eUppercase, eEqStrng, eResLookup, eIdLookup *)

function getAChar: ascii; external;
function getAChar;
 var ch: ascii; i: integer;
 begin
 repeat ch := getChar until ch <> chr(12B);	(* skip over any <lf>'s *)
 i := ord(ch);
 if i < 40B then 				(* or undo ASCII control key *)
   if ((i < 10B) or (15B < i)) and (i <> 30B) then ch := chr(i+100B);
 getAChar := ch;
 end;

procedure out1Line(line,start,length: integer); external;	(* Also in EPUT *)
procedure out1Line;
 begin
 if length > 79 then length := 79;	(* only display first 79 chars *)
 outLine(line,1,start,length);
 end;

procedure clearLine(i: integer); external;
procedure clearLine;				(* copy in ppGlitch *)
 var ch: ascii;
 begin
 ch := listing[1];
 listing[1] := ' ';
 outLine(i,1,1,1);
 listing[1] := ch;
 end;

function upperCase(c: ascii): ascii; external;
function upperCase;
 begin
 if (c < chr(141B)) or (chr(172B) < c) then upperCase := c
  else upperCase := chr(ord(c) - 40B);		(* c - 'a' + 'A' *)
 end;

function eqStrng(s1: strngp; s2,len: integer): boolean; external;
function eqStrng;
 var i,j: integer; b: boolean;
 begin
 b := true;
 i := 0;
 j := 1;
 repeat
  if upperCase(s1↑.ch[j]) <> upperCase(listing[s2+i]) then b := false
   else
    begin
    i := i + 1;
    if j < 10 then j := j + 1
     else begin j := 1; s1 := s1↑.next end;
    end
 until (i >= len) or not b;
 eqStrng := b;
 end;

function hash(ch: ascii): integer; external;
function hash;
 var i: integer;
 begin			(* this will only work for ascii *)
 i := ord(ch);
 if ('A' <= ch) and (ch <= 'Z') then i := i - ord('A') + 1
  else if (chr(141B) <= ch) and (ch <= chr(172B)) then i := i - 141B + 1
  else i := 0;
 hash := i;
 end;

function resLookup(str,len: integer): reswordp; external;
function resLookup;
 var res: reswordp; b: boolean;
 begin
 res := reswords[hash(listing[str])];	(* look in right bucket *)
 b := true;
 while (res <> nil) and b do
  if res↑.length = len then
    if eqStrng(res↑.name,str,len) then b := false
     else res := res↑.next
   else res := res↑.next;
 resLookup := res;
 end;

function idLookup(str,len: integer): identp; external;
function idLookup;
 var id: identp; b: boolean;
 begin
 id := idents[hash(listing[str])];	(* look in right bucket *)
 b := true;
 while (id <> nil) and b do
  if id↑.length = len then
    if eqStrng(id↑.name,str,len) then b := false
     else id := id↑.next
   else id := id↑.next;
 idLookup := id;
 end;

(* aux routines: makeNVar, makeUVar, varLookup *)

function makeNVar(vartype: datatypes; vid: identp): varidefp; external;
function makeNVar;
 var v,vo: varidefp; b: boolean;
 begin
 if curBlock = nil then v := nil else v := curBlock↑.variables;
 vo := nil;
 b := true;
 while (v <> nil) and b do	(* look through var list for free var *)
  if v↑.vtype = freevartype then b := false
   else begin vo := v; v := v↑.next end;
 if v = nil then
   begin
   v := newVaridef;
   with v↑ do
    begin
    next := nil;
    if curBlock = nil then level := 0
     else
      begin
      level := curBlock↑.level;
      with curBlock↑ do numvars := numvars + 1;
      end;
    if vo <> nil then
      begin
      offset := vo↑.offset + 1;
      vo↑.next := v;		(* add var to current block's list of vars *)
      end
     else
      begin
      offset := 0;
      if curBlock <> nil then curBlock↑.variables := v;
       (* *** ??? else ??? *** *)
      end;
    end;
   end;
 with v↑ do
  begin
  vtype := vartype;
  dtype := nil;
  name := vid;
  dnext := nil;
  tbits := 0;
  dbits := 0;
  if vartype = labeltype then s := nil;
  end;
 makeNVar := v;
 end;

function makeUVar(vartype: datatypes; vid: identp): varidefp; external;
function makeUVar;
 var v: varidefp; sp,oldCurBlock: statementp; i: integer; b: boolean;
 begin
 oldCurBlock := curBlock;
 curBlock := cursorStack[2].st;		(* assume outermost block *)
 i := cursor;			(* unless in body of an enclosing procedure *)
 while i > 2 do
  begin
  with cursorStack[i] do
   if not stmntp then 
     if nd↑.ntype = procdefnode then
       if nd↑.body↑.stype = blocktype then
	 begin					(* found one *)
	 curBlock := nd↑.body;
	 b := not(sParse and (i >= sCursor)); (* special case for stmnt parsing *)
	 i := 0
	 end;
  i := i - 1;
  end;
 v := makeNVar(vartype,vid);
 sp := newStatement;	(* add a new declaration statement to start of block *)
 with sp↑ do
  begin
  stype := declaretype; variables := v; numvars := 1;
  next := curBlock↑.bcode;
  if b then
    if newDeclarations = nil then last := curBlock
     else begin last := newDeclarations; newDeclarations↑.next := sp end
   else begin last := curBlock; curBlock↑.bcode := sp end;
  nlines := 1;
  end;
 if b then newDeclarations := sp;
(* fix the display up later - hopefully the variable will be defined by then *)
 curBlock := oldCurBlock;
 makeUVar := v;
 end;

function varLookup(id: identp): varidefp; external;
function varLookup;
 var v: varidefp; i: integer; b: boolean;
 begin
 i := cursor;
 b := true;
 while (i > 1) and b do
  begin
  v := nil;
  with cursorStack[i] do
   if stmntp then begin if st↑.stype = blocktype then v := st↑.variables end
    else if nd↑.ntype = procdefnode then v := nd↑.paramlist;
  while (v <> nil) and b do
   if v↑.name = id then b := false else v := v↑.next;
  i := i - 1;
  end;
 if b then v := id↑.predefined;	(* maybe it's a predefined variable? *)
 varLookup := v;
 end;

(* cursorStack routines: pushStmnt, pushNode *)

procedure pushStmnt(s: statementp; indent: integer); external;
procedure pushStmnt;
 begin
 cursor := cursor + 1;
 with cursorStack[cursor] do
  begin
  cline := curLine + 1;
  if cursor = 1 then ind := indent
   else ind := cursorStack[cursor-1].ind + indent;
  stmntp := true;
  st := s;
  end;
 if (s↑.stlab = nil) or (cursorLine <> curLine + 1) then fieldNum := 1
  else fieldNum := 0;
 if s↑.stype = blocktype then curBlock := s;
 end;

procedure pushNode(n: nodep); external;
procedure pushNode;
 begin
 cursor := cursor + 1;
 with cursorStack[cursor] do
  begin
  cline := curLine + 1;
  if cursor = 1 then ind := 0
   else ind := cursorStack[cursor-1].ind;
  stmntp := false;
  nd := n;
  end;
 fieldNum := 1;
 end;

(* bannerLine, borderLines, & adjustDisplay *)

procedure bannerLine(ch: ascii; l: integer); external;
procedure bannerLine;
 var i: integer; h: packed array [1..27] of ascii; 
     t: real; hr,min: integer;

 procedure digitize(n,i:integer; zfill:boolean);
  var ch: char;
  begin
  listing[i] := chr((n mod 10) + ord('0')); 
  n := n DIV 10;
  ch := chr((n mod 10) + ord('0')); 	(* 2nd char *)
  if (n > 0) or zfill then listing[i-1] := ch;
  n := n DIV 10;
  if n > 0 then listing[i-2] := chr((n mod 10) + ord('0'));
  end;

 begin
 for i := 151 to 190 do listing[i] := ch;
 h := ' Cursor at Line     of     ';
 if l = 0 then		(* Top line *)
   begin		
   for i := 11 to 20 do listing[145+i] := h[i];	(* Clear end of line *)
   digitize(topDline+firstDline-1,164,false);	(* Put in line# at top of scrn *)
   for i:=171 to 190 do listing[i] := ' ';	(* Clear last part of line *)
   if collect then listing[172] := 'C';		(* Flag if Collect is on *)
   if singleThreadMode then       		(* Flag if nowait mode *)
     begin
     listing[175] := 'N'; listing[176] := 'W';
     end;
   t := time;     				(* Find out what time it is *)
   hr := trunc(t);
   min := trunc((t-hr)*60);
   digitize(hr,187,false);			(* Put time into buffer *)
   listing[188] := ':';
   digitize(min,190,true);
   end
  else			(* Bottom line *)
   begin		
   for i := 1 to 27 do listing[155+i] := h[i];
   digitize(cursorline,174,false);		(* Put in line# cursor is at *)
   digitize(dprog↑.nlines,181,false);		(* and total lines in program *)
   end;
 outLine(l,1,151,40);
 end;

procedure borderLines; external;
procedure borderLines;
 var ch: ascii; i: integer;
 begin
 if not fParse then
   begin
   if topDline + firstDline = 2 then ch := '*' else ch := '.';
   bannerLine(ch,0);
   if topDline + firstDline + dispHeight - 2 >= dprog↑.nlines then ch := '*'
    else ch := '.';
   if botDline < dispHeight then bannerLine(ch,botDline+1)
    else bannerLine(ch,dispHeight+1);
   end;
 end;

procedure adjustDisplay; external;
procedure adjustDisplay;
 begin
 if (cursorLine < topDline + firstDline - 1) or
    (cursorLine > topDline + firstDline + dispHeight - 2) then
   lineNum := cursorLine - dispHeight div 2;		(* off screen *)
 end;